home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (DO) / Softdisk Magazette Volume 2, No. 06 (1983-02)(Softdisk)(Side B).zip / Softdisk Magazette Volume 2, No. 06 (1983-02)(Softdisk)(Side B).do / MENU.bas < prev    next >
BASIC Source File  |  1996-12-24  |  3KB  |  88 lines
  1. 3  REM  MENU
  2. 5  TEXT : HOME : VTAB 12: HTAB 12: FLASH : PRINT "LOADING MENU": NORMAL 
  3. 10  POKE 1013,76: POKE 1014,0: POKE 1015,3: FOR X1 = 768 TO 818: READ Y1: POKE X1,Y1: NEXT 
  4. 20 D$ =  CHR$(4):OP$ = D$ +"OPEN  HARVEST.TEXT,L47"
  5. 30 RD$ = D$ +"READ  HARVEST.TEXT,R"
  6. 35 WR$ = D$ +"WRITE  HARVEST.TEXT,R"
  7. 40 CL$ = D$ +"CLOSE  HARVEST.TEXT"
  8. 50  DIM L$(30),L(30)
  9. 60  DIM VL$(500),S%(500),C%(500)
  10. 90  PRINT OP$
  11. 100  PRINT RD$;0: INPUT LF: INPUT VN: &  GET DT$
  12. 110  PRINT D$
  13. 120 RN = 1
  14. 130  GOTO 1000
  15. 200  REM NUMBERINPUT
  16. 210  PRINT D$
  17. 220  INVERSE : PRINT "Q=QUIT  H=HARDCOPY  OR  1-"T;
  18. 225  NORMAL 
  19. 230  GET I$
  20. 240  IF I$ = "Q"  THEN 9000
  21. 250  IF I$ = "H"  THEN  GOSUB 5000: RETURN 
  22. 270 I =  VAL(I$)
  23. 280  IF (I >T)  OR I <1  OR I < > INT(I)  THEN  PRINT "<CTRL-G>";: GOTO 230
  24. 290 RN = RN(I): RETURN 
  25. 400  REM MINPUT
  26. 410  PRINT D$
  27. 420  INVERSE : PRINT "Q=QUIT  H=HARDCOPY  G=GOBACK  M=MORE ";: NORMAL 
  28. 430  GET I$
  29. 440  IF I$ = "Q"  THEN 9000
  30. 450  IF I$ = "H"  THEN  GOSUB 5000: RETURN 
  31. 460  IF I$ = "G"  THEN RN = 1: RETURN 
  32. 480 RN = RN(1): RETURN 
  33. 1000  REM GET PAGE 
  34. 1005 NN = RN
  35. 1010  PRINT RD$;NN
  36. 1020  &  GET T$
  37. 1023  IF T$ < >"D"  THEN 1200
  38. 1026  &  GET TY$
  39. 1040  &  GET T$
  40. 1050 T =  VAL(T$)
  41. 1060  &  GET T$: IF TY$ < >"H"  THEN 1065
  42. 1061  IF  LEFT$(T$,1) = ")"  THEN 6000
  43. 1062  HOME : INVERSE : PRINT "SOFTDISK HARVEST  -  ";DT$;" - FRAME ";RN: NORMAL : PRINT :NL = 0
  44. 1065  PRINT T$:NL = NL +1:L$(NL) = T$:L(NL) = T
  45. 1070  IF T >0  THEN  PRINT :T = T -1: GOTO 1070
  46. 1075  PRINT D$
  47. 1080 NN = NN +1: GOTO 1010
  48. 1200  REM  END OF PAGE
  49. 1220  &  GET T1$: INPUT FV: &  GET T$
  50. 1240 T =  VAL(T$)
  51. 1250  FOR A = 1 TO T: &  GET A$:RN(A) =  VAL(A$)
  52. 1256  NEXT 
  53. 1260  IF T = 1  THEN  GOSUB 400: GOTO 1300
  54. 1270  GOSUB 200
  55. 1300  REM  CONTINUE
  56. 1305  PRINT 
  57. 1310  GOTO 1000
  58. 5000  REM PRINTOUT
  59. 5010  HOME : PRINT : PRINT D$"PR#1"
  60. 5015  PRINT "SOFTDISK HARVEST  -  "DT$" - FRAME "RN
  61. 5017  PRINT 
  62. 5020  FOR A = 1 TO NL
  63. 5030  PRINT L$(A)
  64. 5033 TT = L(A)
  65. 5036  IF TT >0  THEN  PRINT :TT = TT -1: GOTO 5036
  66. 5038  NEXT 
  67. 5040  PRINT 
  68. 5060  IF T = 1  THEN  PRINT "Q=QUIT  H=HARDCOPY  G=GOBACK  M=MORE": GOTO 5080
  69. 5070  PRINT "Q=QUIT  H=HARDCOPY  V=VERBAL  OR 1-"T
  70. 5080  PRINT D$"PR#0": RETURN 
  71. 6000 A$ =  MID$ (T$,2)
  72. 6010  PRINT A$
  73. 6020  PRINT D$;
  74. 6060  PRINT A$: END 
  75. 9000  HOME : INVERSE : GOSUB 9500: PRINT "SOFTDISK IS PLEASED TO HAVE BROUGHT YOU": GOSUB 9500
  76. 9010  PRINT "THIS ABUNDANT SOFTWARE HARVEST.        ": GOSUB 9500: GOSUB 9500
  77. 9020  PRINT "SUBSCRIBERS WHO ARE EAGER TO SHARE     ": GOSUB 9500
  78. 9030  PRINT "APPLE TREASURES HAVE MADE IT POSSIBLE. ": GOSUB 9500: GOSUB 9500
  79. 9040  PRINT "PLEASE CONTACT CONTRIBUTORS IN REGARD  ": GOSUB 9500
  80. 9050  PRINT "TO RIGHTS OTHER THAN DISTRIBUTION IN   ": GOSUB 9500
  81. 9060  PRINT "THE SOFTDISK NETWORK.                  ": GOSUB 9500
  82. 9070  PRINT "            SOFTDISK MAGAZETTE         "
  83. 9080  PRINT "             3811 ST. VINCENT          "
  84. 9090  PRINT "        SHREVEPORT, LOUISIANA 71108    "
  85. 9100  GOSUB 9500: PRINT "$10 TO START               $5 PER MONTH"
  86. 9110  GOSUB 9500: NORMAL : VTAB 23: END 
  87. 9500  PRINT "                                       ": RETURN 
  88. 15000  DATA 201,190,240,3,76,201,222,32,177,0,32,227,223,32,44,213,232,189,0,2,208,250,134,157,138,32,82,228,160,0,145,131,200,165,113,145,131,200,165,114,145,131,160,2,162,0,165,157,76,226,229